// talkparty.txt
// A very simple, naive text. Creature attacks anything it hates nearby.
// Once it has won, it returns to its home.
// If the party approaches this creature, the creature speaks with the 
// party.
// 
// by Terror's Martyr (terrorsmartyr@wi.rr.com)
//    based off of the "wisp.txt" script used in Valley of the Dying Things
// 
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Not used.
//   Cell 4 - Dialogue node to start with when creature approaches party.
//   Cell 5,6 - SDFs to set when creature is finished speaking with party.
//   Cell 7 - Talking node activated when player talks with creature.

begincreaturescript;

variables;

short i,target;
short party_sighted = 0;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if (can_see_char(1000))
		party_sighted = 1;
	if ((get_flag(get_memory_cell(5),get_memory_cell(6)) == 0) && (dist_to_party() <= 8) && (party_sighted > 0)) {
		if (dist_to_party() <= 1) {
			set_flag(get_memory_cell(5),get_memory_cell(6),1);
			begin_talk_mode(get_memory_cell(4));
			}
			else approach_char(ME,random_group_member(0),2);
		}
		else if (my_dist_from_start() >= 1) {
			return_to_start(ME,0);
			}


	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if(get_memory_cell(7) == 0){
		print_str("Talking: You get no response.");
		end();
	}
	else{
		begin_talk_mode(get_memory_cell(7));
	}
break;