// standby.txt
// Acts like basicnpc.txt, except allows the designer to have the character
// abandon all other orders and return to a waypoint, its starting location
// or just to stand still.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4,5 - Stuff done flag.  If both 0, nothing.  Otherwise, when this
//     flag is set to a non-zero value, causes character to stand in place,
//     return to start or go to a waypoint.  (See Cell 6)
//   Cell 6 - Waypoint for creature to return to when the SDF of Cells 4,5
//     is set to a non-zero value.  If set to 10, character will return to
//     its starting place.  If 0, character will stand in place.

begincreaturescript;

variables;

short i,target,standby,sttype;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// Check for standby flag.
	if((get_memory_cell(4) != 0) || (get_memory_cell(5) != 0)){
		standby = get_flag(get_memory_cell(4),get_memory_cell(5));
		if(standby > 0){
			sttype = get_memory_cell(6);
			if(sttype == 0){
				stop_moving(ME);
				end_combat_turn();
			}
			if((sttype > 0) && (sttype < 10)){
				stop_moving(ME);
				if(dist_to_waypoint(ME,sttype) <= 0){
					stop_moving(ME);
					end_combat_turn();
				}
				else{
					if(approach_waypoint(ME,sttype,0) == 1){
						stop_moving(ME);
						end_combat_turn();
					}
				}
			}
			if(sttype >= 10){
				stop_moving(ME);
				if(return_to_start(ME,0) == 1){
					stop_moving(ME);
					end_combat_turn();
				}
			}
		}
	}

	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	// Check for standby flag.
	if((get_memory_cell(4) != 0) || (get_memory_cell(5) != 0)){
		standby = get_flag(get_memory_cell(4),get_memory_cell(5));
		if(standby > 0){
			set_state(START_STATE);
		}
	}

	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;