<![CDATA[
FOCUS program :
-*
-* THIS FOCUS PROGRAM WILL CREATE THE INDIVIDUAL BUDGET SHEETS FOR
-* FRS ACCOUNTS BEGINNING WITH 2 OR 3..
-*
-* To print, copy BUDGET.WP to PC, opeen in WordPad & do the following :
-* Format -> Font -> 8; Courier New
-* Page Setup -> Landscape
-* Margins -> Left : close to 0; Rightt : close to 0; Top : 0.3";
-* Bottom : 0.25"
-*
JOIN CLEAR *
SET PAGE=NOPAGE
-*
-* GET ACCOUNT INFORMATION FOR FIRST ((EARLIEST) FISCAL YEAR.
-*
DEFINE FILE FSFILE
HOR_ACTUAL/P9=ANNUAL_BUDGET-BUDGET_BAL_AVAIL-ENCUMBRANCES;
HOR_OBJ_CODE/A4=ACCT_DGT7_10_SL9;
HOR_ANN_BUDGET/P9=ANNUAL_BUDGET;
TST_ACCT/A1=EDIT(ACCT_6_SL9,'9');
END
TABLE FILE FSFILE
PRINT RESPONSIBLE_PERS ACCT_DESC
HOR_OBJ_CODE DOLLAR_DESC
HOR_ANN_BUDGET HOR_ACTUAL BUDGET_BAL_AVAIL
BY ACCT_6_SL9
ON TABLE HOLD AS FSTMP1
-*
-* Specify accounts to get (fiscal yeaar, object code, etc.)
-*
WHERE (TST_ACCT EQ '2') OR (TST_ACCT EQ '3');
WHERE (((HOR_OBJ_CODE GE '3000') AND (HOR_OBJ_CODE LE '3999')) OR
((HOR_OBJ_CODE GE '4500') AND (HOR_OBJ_CODE LE '4532'))) AND
(HOR_OBJ_CODE NE '3916') AND (HOR_OBJ_CODE NE '3920') AND
(HOR_OBJ_CODE NE '3921');
WHERE FISCAL_YR_SL9 EQ '99';
END
-*
-* GET ACCOUNT INFORMATION FOR PRIOR FFISCAL YEAR.
-*
TABLE FILE FSFILE
PRINT RESPONSIBLE_PERS ACCT_DESC
HOR_OBJ_CODE DOLLAR_DESC
HOR_ANN_BUDGET HOR_ACTUAL BUDGET_BAL_AVAIL
BY ACCT_6_SL9
ON TABLE HOLD AS FSTMP2
-*
-* Specify accounts to get (fiscal yeaar, object code, etc.)
-*
WHERE (TST_ACCT EQ '2') OR (TST_ACCT EQ '3');
WHERE (((HOR_OBJ_CODE GE '3000') AND (HOR_OBJ_CODE LE '3999')) OR
((HOR_OBJ_CODE GE '4500') AND (HOR_OBJ_CODE LE '4532'))) AND
(HOR_OBJ_CODE NE '3916') AND (HOR_OBJ_CODE NE '3920') AND
(HOR_OBJ_CODE NE '3921');
WHERE FISCAL_YR_SL9 EQ '00';
END
-*
-* GET ACCOUNT INFORMATION FOR CURRENTT FISCAL YEAR.
-*
DEFINE FILE FSFILE
HOR_ACTUAL/P9=ANNUAL_BUDGET-BUDGET_BAL_AVAIL;
HOR_OBJ_CODE/A4=ACCT_DGT7_10_SL9;
HOR_ANN_BUDGET/P9=ANNUAL_BUDGET;
TST_ACCT/A1=EDIT(ACCT_6_SL9,'9');
END
TABLE FILE FSFILE
PRINT RESPONSIBLE_PERS ACCT_DESC
HOR_OBJ_CODE DOLLAR_DESC
HOR_ANN_BUDGET HOR_ACTUAL BUDGET_BAL_AVAIL
BY ACCT_6_SL9
ON TABLE HOLD AS FSTMP3
-*
-* Specify accounts to get (fiscal yeaar, object code, etc.)
-*
WHERE (TST_ACCT EQ '2') OR (TST_ACCT EQ '3');
WHERE (((HOR_OBJ_CODE GE '3000') AND (HOR_OBJ_CODE LE '3999')) OR
((HOR_OBJ_CODE GE '4500') AND (HOR_OBJ_CODE LE '4532'))) AND
(HOR_OBJ_CODE NE '3916') AND (HOR_OBJ_CODE NE '3920') AND
(HOR_OBJ_CODE NE '3921');
WHERE FISCAL_YR_SL9 EQ '01';
END
-*
-* COMBINE ACCOUNT INFORMATION FOR ALLL THREE FISCAL YEARS.
-*
MATCH FILE FSTMP3
PRINT RESPONSIBLE_PERS ACCT_DESC
HOR_OBJ_CODE DOLLAR_DESC
HOR_ANN_BUDGET AS ANNUAL_BUDGET_E
HOR_ACTUAL AS HOR_ACTUAL_F
BY ACCT_6_SL9
RUN
FILE FSTMP2
PRINT HOR_ANN_BUDGET AS ANNUAL_BUDGET_C
HOR_ACTUAL AS HOR_ACTUAL_D
BY ACCT_6_SL9
AFTER MATCH HOLD OLD-OR-NEW
END
-RUN
-*
MATCH FILE HOLD
PRINT RESPONSIBLE_PERS ACCT_DESC
HOR_OBJ_CODE DOLLAR_DESC
ANNUAL_BUDGET_E HOR_ACTUAL_F
ANNUAL_BUDGET_C HOR_ACTUAL_D
BY ACCT_6_SL9
RUN
FILE FSTMP1
PRINT HOR_ANN_BUDGET AS ANNUAL_BUDGET_B
HOR_ACTUAL AS HOR_ACTUAL_A
BY ACCT_6_SL9
AFTER MATCH HOLD OLD-OR-NEW
END
-RUN
-*
-* SEPARATE OUT NON-TRAVEL OBJECT CODEES.
-*
TABLE FILE HOLD
PRINT RESPONSIBLE_PERS ACCT_DESC
HOR_OBJ_CODE DOLLAR_DESC
ANNUAL_BUDGET_E HOR_ACTUAL_F
ANNUAL_BUDGET_C HOR_ACTUAL_D
ANNUAL_BUDGET_B HOR_ACTUAL_A
BY ACCT_6_SL9
WHERE (HOR_OBJ_CODE GE '3000') AND (HOR_OBJ_CODE LE '3999');
ON TABLE HOLD AS FSTMP4
END
-*
-* SEPARATE OUT TRAVEL OBJECT CODES.
-*
TABLE FILE HOLD
PRINT RESPONSIBLE_PERS ACCT_DESC
HOR_OBJ_CODE DOLLAR_DESC
ANNUAL_BUDGET_E HOR_ACTUAL_F
ANNUAL_BUDGET_C HOR_ACTUAL_D
ANNUAL_BUDGET_B HOR_ACTUAL_A
BY ACCT_6_SL9
WHERE (HOR_OBJ_CODE GE '4500') AND (HOR_OBJ_CODE LE '4532');
ON TABLE HOLD AS FSTMP5
END
-*
-* SUM TRAVEL OBJECT CODE AMOUNTS INTOO ONE.
-*
DEFINE FILE FSTMP5
TRAV_OBJ_CODE/A4='4500';
TRAV_DESC/A20='TRAVEL';
END
TABLE FILE FSTMP5
SUM RESPONSIBLE_PERS ACCT_DESC
TRAV_OBJ_CODE TRAV_DESC
ANNUAL_BUDGET_E HOR_ACTUAL_F
ANNUAL_BUDGET_C HOR_ACTUAL_D
ANNUAL_BUDGET_B HOR_ACTUAL_A
BY ACCT_6_SL9
ON TABLE HOLD AS FSTMP6
END
-*
-* RECOMBINE THE TWO FILES CREATED ABOOVE.
-*
-RUN
-VMS COPY FSTMP4.FTM,FSTMP6.FTM HOLD.FTTM;
-*
-* CREATE INDIVIDUAL BUDGET SHEETS.
-*
DEFINE FILE HOLD
HOR_BUDGET_REQ/A1=' ';
TST_ACCT/A1=EDIT(ACCT_6_SL9,'9');
END
TABLE FILE HOLD
HEADING
"DATE : &DATEMDYY <+54 (some institution)"
"<+72 DEPARTMENTAL BUDGET REQUEST FORM </1"
PRINT HOR_OBJ_CODE AS 'CODE' IN 45
DOLLAR_DESC AS 'DESCRIPTION' IN 51
HOR_ACTUAL_A AS ' ACTUAL,EXPENDITURE, 1998-1999'
HOR_ACTUAL_D AS ' ACTUAL,EXPENDITURE, 1999-2000' IN 85
ANNUAL_BUDGET_B AS ' BUDGET,ALLOCATIONS, 1998-1999' IN 97
ANNUAL_BUDGET_C AS ' BUDGET,ALLOCATIONS, 1999-2000' IN 109
ANNUAL_BUDGET_E AS ' BUDGET,ALLOCATIONS, 2000-2001' IN 121
HOR_ACTUAL_F AS 'SPENT AS OF,02/28/2000' IN 133
HOR_BUDGET_REQ AS ' BUDGET, REQUEST,2001-2002' IN 145
BY TST_ACCT NOPRINT
BY ACCT_6_SL9 AS 'ACCT #' IN 1
BY RESPONSIBLE_PERS AS 'RESPONSIBLE, PERSON' IN 8
BY ACCT_DESC AS 'DEPARTMENT' IN 23
ON HOR_OBJ_CODE SKIP-LINE
ON TST_ACCT SUBTOTAL AS 'TOTAL FOR ACCT # : '
ON ACCT_6_SL9 SUBTOTAL AS 'TOTAL FOR ACCT # : '
ON ACCT_6_SL9 PAGE-BREAK
FOOTING BOTTOM
"DEPARTMENTAL APPROVAL:"
"DEAN APPROVAL:"
"JUSTIFICATION FOR BUDGET INCREASES:"
" "
" "
" "
" "
ON TABLE SAVE AS BUDGET FORMAT WP
WHERE (HOR_ACTUAL_A NE 0) OR (HOR_ACTUAL_D NE 0) OR
(ANNUAL_BUDGET_B NE 0) OR (ANNUAL_BUDGET_C NE 0) OR
(ANNUAL_BUDGET_E NE 0) OR (HOR_ACTUAL_F NE 0);
WHERE HOR_OBJ_CODE NE '';
END
JOIN CLEAR *
]]>
This page hosted by 
Get your own Free Homepage
