#nop // Written by sqweekette@yahoo.com
#nop // An autoroller... Deluxe Edition :)
#nop // Will keep track of the highest value for each stat, as well as
#nop // adding a Total field to the stat line
#nop // It should be easy enough to change the automatic operation by
#nop // altering the aliases autoAccept and autoDeny...
#nop // It does autoAccept whenever the roll is satisfactory, and autoDeny
#nop // when it's not.
#nop
#nop #presub
#var {statTarget} {90}
#var {strTarget} {0}
#var {wisTarget} {0}
#var {intTarget} {0}
#var {dexTarget} {0}
#var {conTarget} {0}
#var {maxStr} {0}
#var {maxWis} {0}
#var {maxInt} {0}
#var {maxDex} {0}
#var {maxCon} {0}
#alias {autoAccept} {#nop}
#alias {autoDeny} {n}
#alias {setTarget} {#var {statTarget} {%%1}}
#alias {settarget} {setTarget %1}
#alias {setTotal} {setTarget %1}
#alias {settotal} {setTarget %1}
#alias {setStr} {#var {strTarget} {%%1}}
#alias {setstr} {setStr %1}
#alias {setWis} {#var {wisTarget} {%%1}}
#alias {setwis} {setWis %1}
#alias {setInt} {#var {intTarget} {%%1}}
#alias {setint} {setInt %1}
#alias {setDex} {#var {dexTarget} {%%1}}
#alias {setdex} {setDex %1}
#alias {setCon} {#var {conTarget} {%%1}}
#alias {setcon} {setCon %1}
#alias {stop} {#alias {autoAccept} {#nop}; #alias {autoDeny} {#nop}}
#alias {go} {#alias {autoDeny} {n}; n}
#action {Strength: %1 Intelligence: %2 Wisdom: %3 Dexterity: %4 Constitution: %5 %6} {#math {statTotal} {%1+%2+%3+%4+%5}; #if {%1>$maxStr} {#var {maxStr} {%%1}}; #if {%2>$maxInt} {#var {maxInt} {%%2}}; #if {%3>$maxWis} {#var {maxWis} {%%3}}; #if {%4>$maxDex} {#var {maxDex} {%%4}}; #if {%5>$maxCon} {#var {maxCon} {%%5}}; #if {%1>=$strTarget && %2>=$intTarget && %3>=$wisTarget && %4>=$dexTarget && %5>=$conTarget && $statTotal>=$statTarget} {autoAccept} else {autoDeny}}
#substitute {Strength: %1 Intelligence: %2 Wisdom: %3 Dexterity: %4 Constitution: %5} {Strength: %1 Intelligence: %2 Wisdom: %3 Dexterity: %4 Constitution: %5 Total: $statTotal}