VB ActiveX 使用方法(二)

回首頁

分類

標題

大意

作者

日期
TreeView 如何取得 Node 物件的對應訊息 NodeClick Event 老怪 1998/12/10
TreeView 由使用者手動加入 Node Nodes.Add 方法 老怪 1998/12/10
TreeView 鎖住某個 Node 不容許編輯 BeforeLabelEdit 的編輯事件 老怪 1998/5/23
MaskEdBox 消除顯示字元的底線 PromptChar 屬性 老怪 1999/1/15
MsFlexEdit 自動捲動顯示新增資料 TopRow 屬性的作用 老怪 1999/2/5
MsFlexEdit CellText 編輯界面範例 TextBox 配 FlexEdit 老怪 1999/3/12
MsFlexEdit 清除先前的 Cell 設定資料 　 老怪 1999/4/16
MsFlexEdit 在 Cell 中插入圖片 OleObject 物件的使用 老怪 1999/4/23
MsFlexEdit 用程式捲動 Cell 的顯示 TopRow 屬性的使用 老怪 1999/5/16
MsFlexEdit 最適欄寬範例 ColWidth 屬性的使用 老怪 1999/6/3
MsFlexEdit 最適欄高範例 RowHeight 屬性的使用 老怪 1999/6/5
MsFlexEdit MsFlexGrid 與 DBGrid Sort 的比較 　 老怪 1999/6/10
MCIControl 在 PictureBox 播放影片影像 hWndDisplay 屬性的作用 老怪 1999/2/6
CommonDialog 如何偵測對話盒的 Cancel 事件 CancelError=True 老怪 1999/3/5
CommonDialog 如何偵測使用者列印頁數選擇 Flags 屬性的使用 老怪 1999/4/1
SSTab 隱藏頁籤 TabVisible 屬性的使用 老怪 1999/4/19
SSTab 程式執行中設定頁籤的標題 TabCaption 屬性的使用 老怪 1999/5/19
ToolBar 程式控制按下Toolbar的按鈕 Buttons 屬性的使用 老怪 1999/4/24
RichTextBox 列印 RichTextBox 的內容 SelPrint 方法的使用 老怪 1999/4/27
WinSock 如何連續 SendData 數筆資料 善用 SendComplete Event 老怪 1999/5/13

如何取得 Node 物件的對應訊息

tzigane 撰寫於文章

譬如說當滑鼠 click tree中的某一個node時,該node所對應到的物件,譬如說某個多媒體檔便會開啟??

老怪答：

  1. TreeView Node 物件有 Index、Text、Key 三個屬性可供讀取：
  2. 正確選取 Node 方式是 TreeView NodeClick 事件：
    你在 Form 的一般宣告區做
    Dim NodeKey As String
    Dim NodeText As String
    Dim NodeIndex As Integer
    然後在
    Private Sub TreeView1_NodeClick(ByVal Node As ComctlLib.Node)
    Dim TempNode As Node
        Set TempNode = Node
        NodeKey = TempNode.Key
        NodeText = TempNode.Text
        NodeIndex = TempNode.Index
    End Sub
    就可以保留 Node 的選取值而在 Form 的其他程序裏運用。

回索引

由使用者手動加入 Node

'執行本範例請於 Form 上布置 TreeView1、Text1、Command1,2。
Option Explicit
Private Sub Command1_Click()
Dim TempNode As Node
    If TreeView1.Nodes.Count = 0 Then
        Set TempNode = TreeView1.Nodes.Add(, , , Text1.Text)
        Command2.Enabled = True
    Else
        Set TempNode = TreeView1.Nodes.Add(TreeView1.SelectedItem.Index, _
        , , Text1.Text)
    End If

    TempNode.EnsureVisible
    Set TreeView1.SelectedItem = TempNode
    Set TreeView1.DropHighlight = TempNode
End Sub
Private Sub Command2_Click()
Dim TempNode As Node
    Set TempNode = TreeView1.Nodes.Add(TreeView1.SelectedItem.Index _
            , tvwChild, , Text1.Text)
    TempNode.EnsureVisible
    Set TreeView1.SelectedItem = TempNode
    Set TreeView1.DropHighlight = TempNode
End Sub
Private Sub Form_Load()
    Command1.Caption = "增加同層節點"
    Command2.Caption = "增加子節點"

    Command2.Enabled = False
End Sub
Private Sub TreeView1_NodeClick(ByVal Node As ComctlLib.Node)
    Set TreeView1.DropHighlight = Node
End Sub

回索引

消除顯示字元的底線

寄件者: 翡翠鳥 Carlos Jang
新聞群組: tw.bbs.comp.language
日期: 1999年1月14日 13:45
主旨: [VB] 有關 MaskEdBox...

我在資料庫中的日期格式是字串型態形如 "87-12-31"，現在我用一個 MaskEdBox 來連結到這個欄位，>我想讓使用者不須輸入 "-"，所以 mask = "##-##-##"，但執行時有資料的欄位卻變成 "__-__-__"，可以解決這個問題嗎？

老怪答：

Private Sub Form_Load()
    MaskEdBox1.PromptChar = " "
End Sub

回索引

自動捲動顯示新增資料

寄件者: Huang Wei Shin

msflexgrid 物件將資料一筆一筆寫到grid中，是否可以將最新的資料顯示在畫面，而不是要    自己捲動scroll bar去看最新的資料，自動會移動scroll bar。

老怪答：

    Private Sub Command1_Click()
        MSFlexGrid1.AddItem "Item:" & MSFlexGrid1.Rows
        MSFlexGrid1.TopRow = MSFlexGrid1.Rows - 1
    End Sub

回索引

在 PictureBox 播放影片影像

城市獵人 撰寫於文章

MCI控制項要怎麼讓它在picturebox上放出來呢？

老怪答

'測試本範例請於表單布置 MMControl1、Command1、Picture1
Option Explicit
Private Sub Command1_Click()
    MMControl1.Command = "Play"
End Sub
Private Sub Form_Load()
    MMControl1.hWndDisplay = Picture1.hWnd
' Set properties needed by MCI to open.
    MMControl1.Notify = False
    MMControl1.Wait = True
    MMControl1.Shareable = False
    MMControl1.DeviceType = "avivideo"
    MMControl1.filename = "C:\temp\closeup.avi"
    '開啟 MCI WaveAudio 週邊設備。
    MMControl1.Command = "Open"
End Sub
Private Sub Form_Unload(Cancel As Integer)
MMControl1.Command = "Close"
End Sub

回索引

如何偵測對話盒的 Cancel 事件

廣達新一 撰寫於文章

我在程式中用 CommonDialog 控制項的 ShowOpen 方法開啟檔案，我是想..當我按取消的話~~就結束，可是~~~實際上.卻會往下一行繼續執行~~請問這該如何解決??

老怪答：

兩個辦法：

  1. 把 CommonDialog.CancelError=True ，那按 Cancel 鍵就會引發一個錯誤事件，你再依此錯誤事件寫結束程式如：
    Sub Command1_Click
    On Error GoTo CancelError
    CommonDialog1.ShowOpen
    '..................執行它項敘述
    Exit Sub

    CancelError:

    MsgBox Err.Description, vbOKOnly, "錯誤代碼：" & Err.Number
    End Sub
  2. 在 CommonDialog.ShowOpen 之前，先 CommonDialog.FileName=""
    在  CommonDialog.ShowOpen 之後，再用 If 判斷是否 CommonDialog.FileName=""，來決定是否終止程式，如：
    Sub Command1_Click
    CommonDialog.FileName=""
    CommonDialog1.ShowOpen
    If CommonDialog.FileName="" Then
    Exit Sub
    Else
    '..................執行它項敘述
    End If
    End Sub

回索引

CellText 編輯界面範例

MsFlexGrid 怎樣也可以變的讓使用者編修資料，而不只是顯示資料，當然就是在MsFlexGrid 的 Cell 上給它放一個 TextBox ，自然也就可以編輯 Cell 內容囉。

'測試本範例請於 Form 上布置 MsFlexGrid1，Text1
Option Explicit

'記錄原修改的 Cell 座標
Dim ColRec As Long, RowRec As Long

Private Sub Form_Load()
Dim DataItem As String
Dim I As Integer

    Set Text1.Font = MSFlexGrid1.Font
    '先把文字編輯盒藏起來
    Text1.Visible = False

    '設定 FlexGrid 使用三欄
    MSFlexGrid1.Cols = 3

    '加五十筆記錄
    For I = 1 To 50
        MSFlexGrid1.AddItem "品項" & I & Chr(9) & "名稱" & I & Chr(9) _
                & "規格" & I
    Next
End Sub

Private Sub MSFlexGrid1_EnterCell()
    '移動並調整 TextBox 大小，使能放入 FlexGrid 的 Cell 內，
    '並把 Cell 資料放入 TextBox 內。
    With MSFlexGrid1
        ColRec = .Col
        RowRec = .Row
        Text1.Move .Left + .CellLeft, .Top + .CellTop, _
                .CellWidth, .CellHeight
        Text1.Text = .Text
    End With

    '使 TextBox 為可見，並取得焦點。
    With Text1
        .Visible = True
        .SetFocus
    End With
End Sub

Private Sub MSFlexGrid1_LeaveCell()
    '離開某 Cell 進入另一 Cell ，則進行 Cell 資料更新副程式。
    CellDataChange
End Sub

Private Sub Text1_KeyPress(KeyAscii As Integer)
    If KeyAscii = 13 Then
        '在 TextBox 裏按 Enter 鍵 ，也進行 Cell 資料更新副程式。
        CellDataChange
    End If
End Sub

'資料更新副程式
Private Sub CellDataChange()
    MSFlexGrid1.TextMatrix(RowRec, ColRec) = Text1.Text
    Text1.Visible = False
    MSFlexGrid1.SetFocus
End Sub

回索引

如何偵測使用者列印頁數選擇

寄件者: tien

用Commondialog中的showprint，如何偵測使用者何時選的是「列印全部」、「列印選取範圍」？

老怪答：

Private Sub Command1_Click()
    CommonDialog1.ShowPrinter

    If CommonDialog1.Flags And cdlPDSelection Then
        Debug.Print "使用者選擇列印選取範圍"
    Else
        If CommonDialog1.Flags And cdlPDPageNums Then
            Debug.Print "使用者選擇列印頁數"
        Else
            Debug.Print "使用者選擇全部列印"
        End If
    End If
End Sub

回索引

清除先前的 Cell 設定資料

laigs 撰寫於文章

請問在MSFlexGrid，如果已經開一個檔案進來，若想另開一個檔案進來，請問如何清除原有MSFlexGrid中的資料，請高手指點！指點！謝謝！！

老怪答：

要看你當初是怎麼加資料的。

  1. 用 AddItem 加資料的用 RemoveItem 移掉。
  2. 用 Rows=Number ,Cols=Number 加資料的用 Rows=0 ,Cols=0 移資料。
  3. 以設定 DataSource 屬性，用 Data 控制項提供資料的，Data.Recordset 改變 MFlexGrid 會跟著配合改變。

回索引

隱藏頁籤

(魔星) 的文章中提到:

在VB中似乎沒有 Page Control 元件，而 SSTab 元件又沒有 TabVisible 屬性。

老怪答：

SSTab 有 TabVisible 屬性，你可以用在 Tab(0),(1),(2) 分別放 Command1,2,3 ，然
後執行下列 Code 來一一顯示每一頁 Tab：
Private Sub Command1_Click()
    SSTab1.TabVisible(0) = False
    SSTab1.TabVisible(1) = True
    SSTab1.TabVisible(2) = False
    SSTab1.Tab = 1
End Sub
Private Sub Command2_Click()
    SSTab1.TabVisible(0) = False
    SSTab1.TabVisible(1) = False
    SSTab1.TabVisible(2) = True
    SSTab1.Tab = 2
End Sub
Private Sub Command3_Click()
    SSTab1.TabVisible(0) = True
    SSTab1.TabVisible(1) = False
    SSTab1.TabVisible(2) = False
    SSTab1.Tab = 0
End Sub
Private Sub Form_Load()
    SSTab1.TabVisible(0) = True
    SSTab1.TabVisible(1) = False
    SSTab1.TabVisible(2) = False
End Sub

回索引

在 Cell 中插入圖片

與電鍋纏綿的男孩 撰寫於文章

不知道RICHTEXTBOX能不能在文件編輯中含圖片，如果可以怎麼樣做阿?

老怪答：

只可以用 OLE 方式插入圖片，編輯仍由原產生程式編輯之。範例如下：
RichTextBox1.OLEObjects.Add Index,Key,"BMPPathandName","ProgID"
or
RichTextBox1.OLEObjects.Add ,,"BMPPathandName"

回索引

程式控制按下Toolbar的按鈕

披著企鵝皮的狐狸 撰寫於文章

如果我要用程式控制按下Toolbar這物件上的按鈕，該如何寫ㄋ?比如說，按下鍵盤上的F2就等於按下toolbar上的第一個鈕 , 要如何寫才行勒?

老怪答：

Option Explicit

Dim IconState As Byte

Private Sub Form_KeyUp(KeyCode As Integer, Shift As Integer)
    If KeyCode = vbKeyF2 Then
        'Button.Value 只接受 0,1 二數，故不可用 Boolean 型態設定其值，
        '因為 True 值會被換算成 -1 而導致 Err.Eraise
        IconState = Abs(IconState - 1)
        Toolbar1.Buttons(1).Value = IconState
    End If
End Sub

回索引

列印 RichTextBox 的內容

與電鍋纏綿的男孩 撰寫於文章

請問要如何列印RICH TEXT BOX的內容，我的內容中還含有圖片跟文章!!

老怪答：

您可以使用下列的程式碼傳送到 Printer 物件：
RichTextBox1.SelPrint(Printer.hDC)

回索引

如何連續 SendData 數筆資料

【 (倫倫) 的大作中提到: 】

請問一下...我在vb中使用winsock的SendData來傳送資料...但如果我連續使用SendData兩次...例: winsock.SendData a,winsock.SendData b ，常在 a 沒傳完就被結束而去傳 b，要怎麼解決？

四間 撰寫於文章

DoEvents   //在兩個SendData中加入此行即可...目的是讓程式暫停一下。

老怪答：

不好意思，我覺得 DoEvents 方式會造成很大的程式危機，因為如果送的資料很大，或是剛巧網路傳送不是很順，耗時很久的話，你的程式會變的無法預測，試試下面這段Work 不 Work：

'測試本範例請於表單布置 Command1、Winsock1、Timer1
Option Explicit

'要分批傳送的陣列資料
Dim PushArray() As String
'控制傳下一筆的旗標
Dim Sending As Boolean

Private Sub Command1_Click()
    ReDim PushArray(2)
    PushArray(0) = "你的第一個傳送串"
    PushArray(1) = "你的第二個傳送串"
    PushArray(2) = "你的第三個傳送串"

    Timer1.Enabled = True
End Sub

Private Sub Form_Load()
    Timer1.Interval = 30
    Timer1.Enabled = False
End Sub

'要用 Timer 目的在不停偵測 WinSock SendComplete 了沒有
Private Sub Timer1_Timer()
Static SendIndex As Long
    '只有 SendComplete 之後才傳下一筆
    If Not Sending Then
        'Sending 設為 True 表示開始傳資料
        Sending = True
        Winsock1.SendData PushArray(SendIndex)
        If SendIndex >= UBound(PushArray) Then
            SendIndex = 0
            '全部傳完關閉 Timer
            Timer1.Enabled = False
        Else
            SendIndex = SendIndex + 1
        End If
    End If
End Sub

Private Sub Winsock1_SendComplete()
    'Sending 設為 False 表示一筆資料傳完
    Sending = False
End Sub

回索引

用程式捲動 Cell 的顯示

Option Explicit
Dim All As Long
Private Sub Command1_Click()
Dim I As Long
    Data1.Recordset.MoveLast
    Data1.Recordset.MoveFirst

    All = Data1.Recordset.RecordCount
    Timer1.Enabled = True
End Sub
Private Sub Form_Load()
    Timer1.Interval = 1
    Timer1.Enabled = False
End Sub
Private Sub Timer1_Timer()
Static I As Long
    MSFlexGrid1.TopRow = I + 1

    If I < All - 1 Then
        I = Data1.Recordset.AbsolutePosition + 1
        Data1.Recordset.MoveNext
    Else
        I = 0
        Timer1.Enabled = False
    End If
End Sub

回索引

程式執行中設定頁籤的標題

佛云：不可說！ 撰寫於文章

VB中，SStab頁籤的caption在程式執行中要怎麼設定？如，form1，sstab1，上面有三頁…要把第三個頁籤的caption設成“CCC”…

老怪答：

SSTab1.TabCaption(2) = "CCC"

回索引

鎖住某個 Node 不容許編輯

唉! 撰寫於文章

請問,要如何設定才能作成唯讀的呢?他沒有LOCKED=TRUE的屬性值。

老怪答：

必須用另外變數去記錄它的 Locked ，並且在開始編輯事件中取消其編輯。
Option Explicit

'記錄目前作用中節點的變數
Dim MyNode As Node

Private Sub Form_Load()
    '設定 Treeview 控制項屬性。
    TreeView1.LineStyle = tvwRootLines  ' Linestyle 1
    '新增 Node 物件。
    Dim nodX As Node    '宣告 Node 變數。
    '第一個節點帶有文字 'Root' 。
    Set nodX = TreeView1.Nodes.Add(, , "r", "Root")
    '下一個節點是節點 1 ("Root") 的子節點。
    Set nodX = TreeView1.Nodes.Add("r", tvwChild, "child1", "Child")
End Sub

Private Sub TreeView1_BeforeLabelEdit(Cancel As Integer)
    '如果目前作用中節點的Key = "child1"，則不允許編輯。
    If MyNode.Key = "child1" Then
        Cancel = -1
    End If
End Sub

Private Sub TreeView1_NodeClick(ByVal Node As ComctlLib.Node)
    '用 MyNode 參照目前作用中的節點
    Set MyNode = Node
End Sub

回索引

最適欄寬範例

'本範例能讓你在 MsFlexGrid 的 ColCaption 上按兩下，自動調整整欄大小。
Option Explicit
Private Sub MSFlexGrid1_DblClick()
    '只有在 Col Caption 上按兩下，才會讓
    'MSFlexGrid1.RowSel = MSFlexGrid1.Rows - 1
    If MSFlexGrid1.RowSel = MSFlexGrid1.Rows - 1 Then
        'Call 自動調整欄寬的自訂功能函數
        FixColWidth Me, MSFlexGrid1, MSFlexGrid1.ColSel
    End If
End Sub

'自動調整欄寬的自訂功能函數
'參數：
'MyForm:MsFlexGrid 所在 Form 的參照
'Fg:要調整欄寬物件的參照
'ColNo:調整欄位的 Index
Private Sub FixColWidth(MyForm As Form, FG As MSFlexGrid, ByVal ColNo As
Integer)
Dim MeFont As StdFont
Dim ColW As Single, I As Long
    '先存下 MyForm 的字型設定以便區段結束後回復原設定
    Set MeFont = MyForm.Font
    '以點選欄位為使用中欄位
    FG.Col = ColNo

    '比對所有 Row 中那一筆資料最長
    For I = 0 To FG.Rows - 1
        FG.Row = I
        MyForm.Font.Name = FG.CellFontName
        MyForm.Font.Bold = FG.CellFontBold
        MyForm.Font.Italic = FG.CellFontItalic
        MyForm.Font.Size = FG.CellFontSize

        If ColW < MyForm.TextWidth(FG.Text) Then
            ColW = MyForm.TextWidth(FG.Text)
        End If
    Next

    '最長值再加點邊界值做調整的寬度
    FG.ColWidth(ColNo) = ColW + ScaleX(6, vbPixels, MyForm.ScaleMode)
    '回復 MyForm 原字型設定
    Set MyForm.Font = MeFont
End Sub

回索引

最適欄高範例

tom 撰寫於文章

因為英文實在太長了，所以我想把它寫成兩行，可以嗎？

老怪答：

  1. MsFlexGrid.WordWrap=True 就可以自動折行，不須你把它寫成兩行。
  2. MsFlexGrid 的 RowHeight 高度不會自動放大，所以必須自己用程式拉大 RowHeight 的間距，才能看到完整顯示，範例如下：
  3. '範例使用方式：將 Grid 欄寬調至所需大小，按下重排鈕，即可依 CellText
    '長度重新設定每列高度
    '使用本範例，請於表單布置 MsFlexGrid1,Command1
    Option Explicit

    'MsFlexGrid 的 CellText 和 Cell 邊界的間隔寬度
    Private Const BORDERWIDTH As Integer = 6

    Private Sub Command1_Click()
    '記錄原 Cell 的位置
    Dim OldCol As Long, OldRow As Long
    '記錄原 Form 的 Font 設定
    Dim OldFont As StdFont
    '接收重排字串的變數
    Dim AcceptString As String
    '設定 MsFlexGrid.RowHeight 的運算變數
    Dim LineHeight As Single
    '單個 Cell 推算的高度
    Dim WordHeight As Single
    '迴圈計數器
    Dim I As Long, J As Long

        '記錄 Form 的字型設定
        Set OldFont = Me.Font
        '記錄原 Grid 的使用 Cell 位置
        OldCol = MSFlexGrid1.Col
        OldRow = MSFlexGrid1.Row

        '逐列計算 Grid 的每列列高
        For I = 0 To MSFlexGrid1.Rows - 1
            '還原前次列高設定
            LineHeight = 0
            MSFlexGrid1.Row = I

            '逐欄檢查每個 Cell 完整顯示所需高度
            For J = 0 To MSFlexGrid1.Cols - 1
                MSFlexGrid1.Col = J

                '依各 Cell 字型設定計算列高
                Me.Font.Name = MSFlexGrid1.CellFontName
                Me.Font.Bold = MSFlexGrid1.CellFontBold
                Me.Font.Italic = MSFlexGrid1.CellFontItalic
                Me.Font.Size = MSFlexGrid1.CellFontSize
                '用 WrapCell 自訂函數重新依 ColWidth 把 CellText 排成數行。
                AcceptString = WrapText(MSFlexGrid1.Text,
    MSFlexGrid1.ColWidth(J))
                '計算完全顯示重排後的 CellText 所需高度
                WordHeight = Me.TextHeight(AcceptString)

                '若 Grid 列高小於 CellText 所須高度則放大之
                If LineHeight < WordHeight Then
                    LineHeight = WordHeight
                End If
            Next
            '上下各加兩個圖素做邊界
            MSFlexGrid1.RowHeight(I) = LineHeight + ScaleY(BORDERWIDTH,
    vbPixels, Me.ScaleMode)
        Next

        '還原各項設定
        Set Me.Font = OldFont
        MSFlexGrid1.Col = OldCol
        MSFlexGrid1.Row = OldRow
    End Sub

    Private Sub Form_Load()
    Dim CellString As String

        Command1.Caption = "重排"

        '使用者可調欄位寬度
        MSFlexGrid1.AllowUserResizing = flexResizeColumns
        '超過 CellWidth ，CellText 可自動折行。
        MSFlexGrid1.WordWrap = True
        '塞入一些長字串資料
        MSFlexGrid1.Cols = 4
        MSFlexGrid1.Rows = MSFlexGrid1.Rows - 1

        CellString = "1" & Chr(9) & "這樣的問題一開始就容易偏頗：" & Chr(9)
        CellString = CellString + "第一，什麼叫民，你好像認為古中國就只有兩種人，一種叫官，一種叫民。" & Chr(9)
        CellString = CellString + "事實上就算古中國那種不開化的社會，民的組成也十分複雜。"

        MSFlexGrid1.AddItem CellString

        CellString = ""
        CellString = "2" & Chr(9) & "商人算不算民" & Chr(9)
        CellString = CellString + "手工藝者算不算民" & Chr(9)
        CellString = CellString + "小地主算不算民"

        MSFlexGrid1.AddItem CellString

        CellString = ""
        CellString = "3" & Chr(9) & "就算同是自耕農" & Chr(9)
        CellString = CellString + "遭荒地區的自耕農跟豐收地區的自耕農訴求不一樣" & Chr(9)
        CellString = CellString + "土地兼併嚴重和農地自有地區自耕農訴求也不一樣"

        MSFlexGrid1.AddItem CellString

    End Sub

    '依指定寬度將字串重排成數行的自訂函數
    'SendString:重排字串
    'CWidth:重排寬度
    '傳回值:加入分行符號的字串
    Private Function WrapText(ByVal SendString As String, ByVal CWidth As
    Single) As String
    Dim RetString As String
    Dim LineString As String
    Dim SWord As String * 1
    Dim I As Long
        For I = 1 To Len(SendString)
            '逐字取出重排字串
            SWord = Mid(SendString, I, 1)
            '加到單行字串裏
            LineString = LineString & SWord

            '如果加入此 SWord 單字後，超過重排寬度。
            If Me.TextWidth(LineString) > (CWidth - ScaleX(BORDERWIDTH, vbPixels, Me.ScaleMode)) Then
                '把單行字串加入傳回字串，並於結尾加上分行歸位字元
                RetString = RetString & LineString & vbCrLf
                '清除單行字串
                LineString = ""
                '把超過的單字加入下一個單行字串
                LineString = LineString & SWord
            End If
        Next

        '把最後一行加入傳回字串
        RetString = RetString & LineString

        WrapText = RetString
    End Function

回索引

MsFlexGrid 與 DBGrid Sort 的比較

  1. MsFlexGrid 控件的欄位排序，是直由控件本身直屬屬性操作，語法是：
    MsFlexGrid1.Sort=ColIndex (整數值)
  2. DBGrid 則控件本身沒有 Sort 的屬性或方法，只能由 Data Control 提供有排序的記錄給它。

回索引

回首頁

1